Palo Community Forum

Source code

Private Function ConnectToPaloServer(server As String) As Boolean

    Dim retval As Variant
    Dim connectionStatus As Variant
    Dim connectionInfo As Variant
    Dim nextTry As Boolean
    Dim success As Boolean

    Dim obj As Jedox_Palo_XlAddin.IPaloEngineCom
    Set obj = New Jedox_Palo_XlAddin.ComInterface

    On Error GoTo ConnectToPaloServer_Error

    'ggf. Verbindung auf "online" stellen
    retval = RegValueGet(HKEY_CURRENT_USER, RegKey & server & "\", "connected", connectionStatus)
    If connectionStatus <> "true" Then _
        retval = RegValueSet(HKEY_CURRENT_USER, RegKey & server & "\", "connected", "true")

    obj.ForceServerListUpdate

    On Error Resume Next
    Do
        success = False
        nextTry = False
        connectionInfo = obj.GetConnectionDataInfo(server)

        Select Case Err.Number
            Case 0:
                If connectionInfo(0) = "" Then
                    success = True
                    nextTry = False
                Else
                    retval = MsgBox(connectionInfo(0), vbAbortRetryIgnore)
                    nextTry = (retval = vbRetry)
                End If
            Case Else:
                retval = MsgBox("Anmeldung am Palo Server fehlgeschlagen.", vbAbortRetryIgnore)
                nextTry = (retval = vbRetry)
        End Select
        Err.Clear
        
    Loop While nextTry

    ConnectToPaloServer = success

    On Error GoTo 0
    Exit Function

ConnectToPaloServer_Error:

    Debug.Print "Error " & Err.Number & " (" & Err.Description & ") in procedure ConnectToPaloServer of Modul PaloServerRegistration"

    ConnectToPaloServer = False

End Function